uboot-phytec

/*

 * String handling functions for PowerPC.

 *

 * Copyright (C) 1996 Paul Mackerras.

 *

 * This program is free software; you can redistribute it and/or

 * modify it under the terms of the GNU General Public License

 * as published by the Free Software Foundation; either version

 * 2 of the License, or (at your option) any later version.

 */

#include <ppc_asm.tmpl>

#include <asm/errno.h>

​

    .globl  strcpy

strcpy:

    addi    r5,r3,-1

    addi    r4,r4,-1

1:  lbzu    r0,1(r4)

    cmpwi   0,r0,0

    stbu    r0,1(r5)

    bne 1b

    blr

​

    .globl  strncpy

strncpy:

    cmpwi   0,r5,0

    beqlr

    mtctr   r5

    addi    r6,r3,-1

    addi    r4,r4,-1

1:  lbzu    r0,1(r4)

    cmpwi   0,r0,0

    stbu    r0,1(r6)

    bdnzf   2,1b        /* dec ctr, branch if ctr != 0 && !cr0.eq */

    blr

​

    .globl  strcat

strcat:

    addi    r5,r3,-1

    addi    r4,r4,-1

1:  lbzu    r0,1(r5)

    cmpwi   0,r0,0

    bne 1b

    addi    r5,r5,-1

1:  lbzu    r0,1(r4)

    cmpwi   0,r0,0

    stbu    r0,1(r5)

    bne 1b

    blr

​

    .globl  strcmp

strcmp:

    addi    r5,r3,-1

    addi    r4,r4,-1

1:  lbzu    r3,1(r5)

    cmpwi   1,r3,0

    lbzu    r0,1(r4)

    subf.   r3,r0,r3

    beqlr   1

    beq 1b

    blr

​

    .globl  strlen